Create shortcuts for Symbols

[nsm51]

There are a lot of features to create shortcuts or custom links from customize.

Can any shortcut be assigned a Symbol so that one-click can select symbol.

Ofcourse, we can config a Watchlist but in my case, if i need a quick symbol a few times an hour if i am trading, then it is still a couple of clicks or i have to type a few chars in symbol dropdown.

[Milosz]

In my opinion using watchlists for that is still the best and for sure the most straightforward option.

Ofcourse, we can config a Watchlist but in my case, if i need a quick symbol a few times an hour if i am trading, then it is still a couple of clicks..

@nsm51 that is not exactly true, because in case of watchlists you only need one click to change a symbol

Button to Remove Symbol from Watchlist

But don't forget, that with ctrl key pressed you can select/deselect multiple symbols. During this procedure you can even switch to other windows, do some other things and later come back to the list to continue this procedure (the symbols stay selected untill you select one of them without ctrl key pressed) and remove all choosen symbols at once. Pressing the keyboard shortcut only once, clicking OK button only once and confirming performing operation on multiple symbols only once, will allow …

You can make your watchlist always visible using a pinup button (in the upper right corner of Symbols list) or by dragging it and docking as a separate window. See here: https://www.amibroker.com/guide/h_customizeui.html

But (if you really insist) because you can change the Symbol programatically (here is the simplest example changing currently selected chart to "CDR"):

if( ParamTrigger( "Change Symbol", "Press here" ) )

{
    AB = CreateObject( "Broker.Application" );
    doc = AB.ActiveDocument;
    doc.Name = "CDR";
}

How To Synchronize Linked Charts and chart panes to selected Foreign Ticker

@beppe Thank you for showing the example of using ShellExecute() to pass arguments to jscript file. I did't know it is possible and haven't seen similar examples. Below is my code rewritten to use this approach. This solution consists of two codes. Java script file - in this case RelativePerformance.js which is located in Amibroker's Scripts folder: // Jscript code AB = new ActiveXObject( "Broker.Application" ); var objArgs = WScript.Arguments; if (objArgs.Count() == 0) WScript.Echo("No parame…

...or change programatically chart interval:

Change chart interval every 20 seconds

hi all is there a function which can help to code the change interval in the afl automatically every 15 secs to 1 min , 5 min , 60 min, daily in a loop of 15 seconds how to get the sleep or timeout in a loop so that interval can be changed every 15 secs automatically regards thanks in advance

Changing chart's interval using chart parameters' slider

Hello, Recently my friend, who is a candlesticks' enthusiast (and likes to test and look for different patterns in several less popular intervals), asked me if it would be possible to change chart's interval using chart parameter's slider. I knew it is doable and wrote a simple code allowing to do that. Because I thought that it might be also useful for other users, here it is: _SECTION_BEGIN( "Custom Chart Interval v 1.0" ); // By Milosz Mazurkiewicz /// @link https://forum.amibroker.com/t/ch…

... it can be done. You can create your own shortcuts either using Gui Buttons or custom toolbar shortcuts/buttons (a few other ways would be also possible)

Built in Browser vs External. Custom toolbar buttons/shortcuts. Small icons instead of text buttons in the toolbar

Yes it can be done. You can create your own toolbar button(s) or shortcut(s) to AmiBroker's custom tool item(s) (Main menu ---> Tools). There are many possible applications - a quote from: https://www.amibroker.com/guide/w_customize.html Custom tool menu items allow launching executable files (.exe), script files (.js, .vbs), web pages (.html) and any other registered file types from the tools menu. For example: [Toolbar%20Buttons] If you just want to open some predefinied web page in a…

Also remember that if you just switch between a few symbols back and forth, you can simply use Ctrl + Alt + Left Arrow and Ctrl + Alt + Right Arrow to change their charts:

History
Allows to move Back/Forward in 'browser-like' way.

• Previous move to previous symbol (keyboard shortcut: Ctrl+Alt+LEFT)
• Next move to next symbol (keyboard shortcut: Ctrl+Alt+RIGHT)

http://www.amibroker.com/guide/m_view.html

Lastly, remember about the Symbol finder window (F3 shortcut) https://www.amibroker.com/guide/w_finder.html

[Cougar]

@nsm51,

So you do not want to click on a Watchlist and select a symbol.

Like @Milosz pointed out that would be ideal, however, I imagine you might want to hide the Watchlist section or might have long Watchlists. And during heat of intensive day trading simply toggle to some other Symbol instead of recalling the steps to reach that Symbol. Sometime back I had written a code but the subject is irrelevant to this topic. Anyways, here is a modified version of it tailored to your requirement. Hope it helps!

procedure SymGfxTxtWdth( List ) {
	 if( !Nz( StaticVarGet( "InitGfxTxtSz" + GetChartID() ) ) ) {
		 StaticVarSet( "InitGfxTxtSz" + GetChartID(), 1, False );
		 GfxTxtSz = 0;		 
		 for( i = 0; ( sym = StrExtract( List, i, ',' ) ) != ""; i++ ) GfxTxtSz = IIf( GfxGetTextWidth( sym ) > GfxTxtSz, GfxGetTextWidth( sym ), GfxTxtSz );
		 StaticVarSet( "GfxTxtSz" + GetChartID(), GfxTxtSz, False );
	 }
}

function SymPicker( SymList ) {
	 IsErr = 0;
	 if( GetAsyncKeyState( 17 ) < 0 && GetAsyncKeyState( 116 ) < 0 ) { // 17 = Ctrl, 116 = F5
		 SymGfxTxtWdth( SymList );
		 SymCount = StrCount( SymList, "," ) + 1;
		 BtnWidth = StaticVarGet( "GfxTxtSz" + GetChartID() );	 BtnHight = 20; 	BtnOffsetXY = 3;
		 
		 // Stipulated GUI Area
		 TopLeftPxX = 10;							TopLeftPxY = 20;
		 BotRghtPxX = 200;							BotRghtPxY = 200;
		 // GfxFillSolidRect( TopLeftPxX, TopLeftPxY, BotRghtPxX, BotRghtPxY, colorGrey40 );
		 if( SymCount > floor( BotRghtPxY / ( BtnHight + 2 * BtnOffsetXY ) * BotRghtPxX / ( BtnWidth + 2 * BtnOffsetXY ) ) ) IsErr = 1;
		 else {
			 id = GuiGetEvent( 0, 0 );					event = GuiGetEvent( 0, 1 );			 
			 GfxSelectPen( colorBlack, 1 );				GfxSelectSolidBrush( colorWhite );
			 GuiBtnPxX = TopLeftPxX + BtnOffsetXY;		GuiBtnPxY = TopLeftPxY + BtnOffsetXY;
			 for( i = 1; i <= SymCount; i++ ) {
				 // Drawing the GUI Buttons
				 GuiButton( StrExtract( SymList, i - 1, ',' ), i, GuiBtnPxX, GuiBtnPxY, BtnWidth, BtnHight, 1 );
				 if( GuiBtnPxY > BotRghtPxY - BtnHight - BtnOffsetXY ) {
					 GuiBtnPxX += BtnWidth + BtnOffsetXY;
					 GuiBtnPxY = TopLeftPxY + BtnOffsetXY;
				 }
				 else GuiBtnPxY += BtnHight + BtnOffsetXY;
				 // Event triggers upon GUI Button clicks
				 if( id == i && event ) {
					 Ticker = StrExtract( SymList, i - 1, ',' );
					 fC = Foreign( Ticker, "C" );
					 if( !IsNull( fC[ 0 ] ) ) {
						 App = CreateObject( "Broker.Application" );
						 AppActvDoc = App.ActiveDocument;
						 AppActvDoc.Name = Ticker;
						 IsErr = 0;
					 }
					 else IsErr = 2;
				 }
			 }
		 }
	 }
	 else
		 if( !IsNull( StaticVarGet( "InitGfxTxtSz" + GetChartID() ) ) ) StaticVarSet( "InitGfxTxtSz" + GetChartID(), Null, False );
	 return IsErr;
}

_SECTION_BEGIN( "Dynamic Symbol Picker" );
	 // Using ParamStr here but you could use any other list type
	 FreqSymList = ParamStr( "Freq. Symbol list (comma-separated)", "EURUSD,GBPUSD,JPYUSD,USDCAD" ); // "Freq" means Frequent, "Sym" means Symbol
	 err = SymPicker( FreqSymList );
	 switch( err ) {
		 case 1:
			 ErrTxt = "Too many GuiButtons to fit in the stipulated area.\nChoose Parameters from Right-click menu and remove some of the unwanted symbols.";
			 if( !Nz( StaticVarGet( "PopupErr" + GetChartID() ) ) ) {
				 StaticVarSet( "PopupErr" + GetChartID(), 1, False );
				 PopupWindow( ErrTxt, "Error 99", 10, -1, -1, -1, -1, 1 );
			 }
			 Error( ErrTxt );
			 break;
		 case 2:
			 ErrTxt = "No such symbol exist.\nCheck and change the Parameter string list.";
			 if( !Nz( StaticVarGet( "PopupErr" + GetChartID() ) ) ) {
				 StaticVarSet( "PopupErr" + GetChartID(), 1, False );
				 PopupWindow( ErrTxt, "Error 99", 10, -1, -1, -1, -1, 1 );
			 }
			 Error( ErrTxt );
			 break;		 
		 default: // No error
			 SetChartOptions( 1, chartShowDates );
			 Plot( C, "Price", colorDefault, styleCandle );
			 if( !IsNull( StaticVarGet( "PopupErr" + GetChartID() ) ) ) StaticVarSet( "PopupErr" + GetChartID(), Null, False );
			 /* Do something else */
			 break;
	 }
_SECTION_END();

// The timed refresh is just for testing purposes which might be unnecessary during live datafeed and/or as per other segment(s) of your code.
// Also read this KB - When and how often AFL code is executed? (https://www.amibroker.com/kb/2015/02/03/when-and-how-often-afl-code-is-executed/).
RequestTimedRefresh( 1 );
/*_______________________________________________________________________________________________________________________
|This code is for AmiBroker Formula Language (AFL) learning (non-commercial) purposes only. Please do not copy this code|
|(or any other version of it) and paste it over on other forums or anywhere else on the Internet or in any other form	|
|without the AmiBroker Forum owner's consent (https://forum.amibroker.com/).                                            |
_______________________________________________________________________________________________________________________*/
// https://forum.amibroker.com/t/create-shortcuts-for-symbols/15573/3?u=cougar

Usage:

Press and hold Ctrl & F5 together for the GUI Buttons to populate on chart. While Ctrl & F5 are held down, click on the GuiButton for desired symbol to show-up in the ActiveDocument. Release the keys once done. You may also change the hotkey combination(s) by changing the argument of GetAsyncKeyState() directly from the code.

Otherwise as shown in the examples sought by Milosz, you could also create a customized toolbar.

[nsm51]

thanks guys for all your suggestions.
I will read and try them over the weekend.

One alternative that i'm using is to run my formula with Foreign ticker fixed in it on another sheet of my working chart sheet.
so in one click i can swap through some sheets each with fixed symbol.
only drawback is that if the main ticker has holes or some data inconsistency then the charting is a bit different.

@Tomasz I hope we can have some buttons from customize that can be set out-of-the-box in the future. Thanks

[Cougar]

@nsm51,

Not sure what you mean by "out-of-the-box", but you can create custom Button(s) and put that in any of the toolbar. Try the steps below if that solves.

Step 1:

Using any Text Editor (like Notepad.exe) write simple two-liner .js for each symbol separately for which you want a single-click symbol picker button. And Save those in the Drive where AmiBroker is installed, preferably in AmiBroker\Scripts folder, however not necessarily, you can save those anywhere but make sure to put the correct path of those .js file in the next step.

EURUSD.js

var App = new ActiveXObject( "Broker.Application" );
App.ActiveDocument.Name = "EURUSD";

GBPUSD.js

var App = new ActiveXObject( "Broker.Application" );
App.ActiveDocument.Name = "GBPUSD";

Step 2:

Repeat this process for each one of .js from main AmiBroker application window.

Tools -> Customize -> Tools -> New -> Type [Symbol Name] -> Type "Command" as [Full File Path of .js that you just created] -> Close

Step 3:

Then follow the steps as discussed in this KB. The only difference in this case is that while the Customize dialog box is open, you would need to select the Tools menu (instead of View menu) from the Menu bar to drag and drop those User defined tools that you see there in any toolbar of your choice.

Done!



P.S. If you wish to further customize your buttons, you may also refer to the Advanced customizable toolbars, menus and keyboard shortcuts section from the User interface customization guide.

[nsm51]

this should work for me, thanks
for those who have a lot of symbols/watchlist would understand how useful such a one-click go-to a symbol is

Out-of-the-box would be relatively very simple to-do for the developer is what i meant.
for example, In above solution, we would have a multi-AB instance problem

[Metamega]

Just don’t think theirs demand for it. Easy way Is have separate chart and just go through MDI tabs at top. Can symbol lock the chart and that’s it. Or most have another monitor that you could just symbol lock a chart on or a couple and that’s it. Or you press a hot key to search symbol and type a few letters and your on that symbol.

[nsm51]

thanks for your suggestion but

type a few letters

this slower back-and-forth inconvenience stemmed the idea in the first place. i wrote in opening post

have separate chart

this is resource intensive and i can regard as just a suggestion from another user

Or most have another monitor

not practical all the time IMHO

Just don’t think theirs demand for it.

possible, hence the suggestion to Tomasz

[sanjin]

Very helpful, thank @Cougar

[rharsha]

Thank you @Cougar. This is very useful.
How can one go about making the following modifications?

1. Dynamically Populate FreqSymList from the list of active windows

2. Not Hold Ctrl + F5 , till the symbol is selected. User can initially press Ctrl + F5 and then leave it
   This will show up the drop down list, from which user can select the symbol.

   If No symbol is selected , say within 5 seconds, the drop down list is no longer shown

I am still learning AFL, so all of this is very advanced for me.

[Tomasz]

I don’t see the purpose of that. You can simply setup a watchlist and go up/down immediately using arrows and that without ANY coding at all.

Or you can use Favorities

[amisur]

Thanks for sharing the code. Which section of the code needs to be modified If I want to display the buttons always without using the Ctrl + 5 commands.