How to limit the number of trades per position EACH symbol

AFL Programming
1

Hello everyone.

I am trying to find a way to entry signal (long/short) positions that are repeatedly (multiple) limited until an exit signal (sell/short) appears for each stock/symbol in my watch list.

for example :
EntryLimit = 3 ;
Buy signals appear 3x, (buy1, buy2, buy3), and buy4 are ignored until the sell signal appears. likewise for short signals which are limited until the cover signal appears for each symbol.

maybe there is advice or help, I will be grateful

Thank you for your attention.

2

You can use scale-in signals and limit those to 3.

For those types of conditions I usually prefer to use loops (instead of array only) to keep track of the number of scale-ins.

https://www.amibroker.com/guide/h_pyramid.html

1 Like
3

thank you for the advise. :slightly_smiling_face:

unfortunately my code does a continuous entry untill the rule change. If only 1 symbol can be used a limit with MaxOpenPositions but I have more than 1 symbol.

I found a similar topic here using CBT
https://forum.amibroker.com/t/max-opened-positions-per-bar/5922

SetCustomBacktestProc("");

if (Status("action") == actionPortfolio) 
{
    bo = GetBacktesterObject();	//  Get backtester object
    bo.PreProcess();	//  Do pre-processing (always required)

    for (i = 0; i < BarCount; i++)	//  Loop through all bars
    {
        k = 0;
        for (sig = bo.GetFirstSignal( i ); sig; sig = bo.GetNextSignal( i ) )
        {	
              // do your custom signal processing
              
              if( ++k > 5 ) sig.Price = -1; // tell backtester to ignore signal
              
        }	
        
        bo.ProcessTradeSignals( i );	//  Process trades at bar (always required)
    }	  
      
    bo.PostProcess();	//  Do post-processing (always required)
}
4

http://www.amibroker.com/kb/2015/09/26/limit-number-of-trades-per-day-in-a-backtest/

SetCustomBacktestProc(""); 

if( Status( "action" ) == actionPortfolio )
{
    bo = GetBacktesterObject();	//  Get backtester object
    bo.PreProcess();	//  Do pre-processing (always required)


    for( i = 0; i < BarCount; i++ )	//  Loop through all bars
    {
        if(newday[i]==1)
        {
			count=0;
			
        }

        for( sig = bo.GetFirstSignal( i ); sig; sig = bo.GetNextSignal( i ) )
        {
            if( sig.IsEntry())
            {
                if( count< 2 )
                    count ++;
                else
                    sig.Price = -1 ; // ignore entry signal
            }
        }

        bo.ProcessTradeSignals( i );	//  Process trades at bar (always required)
    }

    bo.PostProcess();	//  Do post-processing (always required)
}
5

From reading the first post, I thought you wanted to allow 3 entries in the same symbol over several bars (I didn't understand that you wanted to limit entries per bar)

If you say that your entry signals are continuous (I assume that your Buy/Short variables are true for sevral bars) you might also explore Backtest Modes available like backtestRegularRawMulti where you can have more than one entry per symbol. https://www.amibroker.com/guide/afl/setbacktestmode.html

One final comment on the code below: it limits entry signals to 2 each day and if you have several symbols in your backtest you might have more than 2 entry signals per bar/day.

 for( sig = bo.GetFirstSignal( i ); sig; sig = bo.GetNextSignal( i ) )
        {
            if( sig.IsEntry())
            {
                if( count< 2 )
                    count ++;
                else
                    sig.Price = -1 ; // ignore entry signal
            }
        }
1 Like
6

One additional post with a very simple code snippet just to illustrate the idea of adding to same position via scale-in (in this case it is limited to 4 entries in the same symbol)

Buy=Cross(C,MA(C,5));
Short=Cross(MA(C,5),C); 
Sell=Cross(MA(C,50),C);
Cover=Cross(C,MA(C,50));

Ladd=0;
Sadd=0; 
Max_scalein=4;

for( i = 0; i < BarCount; i++ )
{
	
	if ( Buy[i]==1 && Ladd<=max_scalein)
	{		
		Buy[i]=sigScaleIn;
		Ladd=Ladd+1;
	}
	if (Sell[i]==1)
	{		
		Sell[i]=1;
		Ladd=0;
	}

	if (Short[i]==1 && Sadd<=Max_scalein)
	{		
		Short[i]=sigScaleIn;
		Sadd=Sadd+1;
	}
	if (Cover[i]==1)
	{		
		Cover[i]=1;
		Sadd=0;
	}
	
}
1 Like
7

sorry for late respond and thank you for your help.

it limits entry signals to 2 each day and if you have several symbols in your backtest you might have more than 2 entry signals per bar/day.

this information and input is useful, so my job here is 1. put no limit for days. 2. The limit is only for a maximum scale of buy / short.

1 Like
8

If your limit is only in number of scale-ins per symbol you can start with the example above, where entries are limited to 4 (1 initial entry + 3 scale-ins) and adjust it based on your preferences/definitions.

9 
n = Name();

switch( Name() )
{
   case "SymbolA":
    // strategy A
    Buy = ...;
    Sell = ...;
    break;

   case "SymbolB":
    // strategy B
    Buy = ...;
    Sell = ...;
    break;

   case "SymbolC":
    // strategy C
    Buy = ...;
    Sell = ...;
    break;

   case "SymbolD":
    // strategy D
    Buy = ...;
    Sell = ...;
    break;
}

it can limit per symbol but will become very long code

10

example:

TriggerPrice1 = Ref( HHV( High, 50 ), -1 );
TriggerPrice2 = Ref( HHV( High, 30 ), -1 );

Buy1 = High > TriggerPrice1;
Buy2 = High > TriggerPrice2;

ExitPrice1 = Ref( LLV( Low, 50 ), -1 );
ExitPrice2 = Ref( LLV( Low, 30 ), -1 );

Sell1 = Low < ExitPrice1;
Sell2 = Low < ExitPrice2;

InTrade = 0;

Buy = 0;
Sell = 0;

for( i = 0; i < BarCount; i++ )
{
	switch( InTrade )
	{
	case 0: // not in trade
		if( Buy1[ i ] ) 
			InTrade = Buy[ i ] = 1;
		else
		if( Buy2[ i ] )
			InTrade = Buy[ i ] = 2;;
		
		break;
		
	case 1: // in trade mode 1 - HHV 50 entry
		if( Sell1[ i ] ) 
		{
			Sell[ i ] = InTrade;
			InTrade = 0; 
		}
		break;

	case 2: // in trade mode 2 - HHV 30 entry
		if( Sell2[ i ] ) 
		{
			Sell[ i ] = InTrade;
			InTrade = 0; 
		}
		break;
	}
}